*****pgm: age_adj_mean.do****

use "C:\NHANES\Data\analysis_data.dta", clear

***create variable codes*****
gen     age=1 if ridageyr >=20 & ridageyr <40
replace age=2 if ridageyr >=40 & ridageyr <60
replace age=3 if ridageyr >=60 & ridageyr <.

*create variable for proportions to standardize age
gen std_wgt=.3966 if age==1
replace std_wgt=.3718 if age==2
replace std_wgt=.2316 if age==3

gen     race=1 if ridreth1==3
replace race=2 if ridreth1==4
replace race=3 if ridreth1==1
replace race=4 if ridreth1==2 | ridreth1==5

****format variables******
label define agefmt 1 "20-39"
label define agefmt 2 "40-59", add
label define agefmt 3 "60+", add

label define racefmt 1 "NH White", 
label define racefmt 2 "NH Black", add
label define racefmt 3 "Mex American", add
label define racefmt 4 "Other race/ethn", add

label define sexfmt 1 "male"
label define sexfmt 2 "female", add

label values age agefmt
label values riagendr sexfmt
label values race racefmt

log using "c:\NHANES\log\adjmeans.log", replace

****specify survey design variables****
svyset sdmvpsu [pweight=wtmec4yr], strata(sdmvstra) vce(linearized)

svy, subpop(if ridageyr >=20 & ridageyr <.): mean ridageyr, over(race)
svy, subpop(if ridageyr >=20 & ridageyr <.): mean ridageyr, over(riagendr)

*age adjusted
svy, subpop(if ridageyr >=20 & ridageyr <.): mean bmxbmi, stdize(age) stdweight(std_wgt)
svy, subpop(if ridageyr >=20 & ridageyr <.): mean bmxbmi, stdize(age) stdweight(std_wgt) over(riagendr)
svy, subpop(if ridageyr >=20 & ridageyr <.): mean bmxbmi, stdize(age) stdweight(std_wgt) over(race)
svy, subpop(if ridageyr >=20 & ridageyr <.): mean bmxbmi, stdize(age) stdweight(std_wgt) over(riagendr race)


*unadjusted
svy, subpop(if ridageyr >=20 & ridageyr <.): mean bmxbmi
svy, subpop(if ridageyr >=20 & ridageyr <.): mean bmxbmi, over(riagendr)
svy, subpop(if ridageyr >=20 & ridageyr <.): mean bmxbmi, over(race)
svy, subpop(if ridageyr >=20 & ridageyr <.): mean bmxbmi, over(riagendr race)

log close