*****pgm: age_adj_prev.do****

use "C:\NHANES\Data\analysis_data.dta", clear

***create variable codes*****
gen     age=1 if ridageyr >=20 & ridageyr <40
replace age=2 if ridageyr >=40 & ridageyr <60
replace age=3 if ridageyr >=60 & ridageyr <.

*create variable for proportions to standardize age
gen std_wgt=.3966 if age==1
replace std_wgt=.3718 if age==2
replace std_wgt=.2316 if age==3

gen     race=1 if ridreth1==3
replace race=2 if ridreth1==4
replace race=3 if ridreth1==1
replace race=4 if ridreth1==2 | ridreth1==5

*code to define mean blood pressure measures

gen n_sbp= !missing(bpxsy1)+ !missing(bpxsy2)+ !missing(bpxsy3)+ !missing(bpxsy4)
gen n_dbp= !missing(bpxdi1)+ !missing(bpxdi2)+ !missing(bpxdi3)+ !missing(bpxdi4)

replace bpxdi1=. if bpxdi1==0
replace bpxdi2=. if bpxdi2==0
replace bpxdi3=. if bpxdi3==0
replace bpxdi4=. if bpxdi4==0

egen mean_sbp = rowmean(bpxsy1 bpxsy2 bpxsy3 bpxsy4)
egen mean_dbp = rowmean(bpxdi1 bpxdi2 bpxdi3 bpxdi4)

gen hbp_trt=1 if bpq050a==1
replace hbp_trt=0 if hbp_trt !=1 & (bpq020==1 | bpq020==2) 

gen sbp140=1 if mean_sbp>=140 & mean_sbp<. & ((n_sbp >0 & n_sbp <.) & (n_dbp >0 & n_dbp <.)) 
replace sbp140=0 if sbp140 !=1 & ((n_sbp >0 & n_sbp <.) & (n_dbp >0 & n_dbp <.)) 

gen dbp90=1 if mean_dbp>=90 & mean_dbp<. & ((n_sbp >0 & n_sbp <.) & (n_dbp >0 & n_dbp <.)) 
replace dbp90=0 if dbp90 !=1 & ((n_sbp >0 & n_sbp <.) & (n_dbp >0 & n_dbp <.)) 

gen hbp=1 if (hbp_trt==1 | sbp140==1 | dbp90==1) & ((hbp_trt>=0 & hbp_trt<.) & (sbp140>=0 & sbp140<.) & (dbp90>=0 & dbp90<.))
replace hbp=2 if hbp !=1 & ((hbp_trt>=0 & hbp_trt<.) & (sbp140>=0 & sbp140<.) & (dbp90>=0 & dbp90<.))

gen hbpx=100 if hbp==1
replace hbpx=0 if hbp==2

****format variables******
label define agefmt 1 "20-39"
label define agefmt 2 "40-59", add
label define agefmt 3 "60+", add

label define racefmt 1 "NH White", 
label define racefmt 2 "NH Black", add
label define racefmt 3 "Mex American", add
label define racefmt 4 "Other race/ethn", add

label define sexfmt 1 "male"
label define sexfmt 2 "female", add

label values age agefmt
label values riagendr sexfmt
label values race racefmt

log using "c:\NHANES\log\adjprev.log", replace

****specify survey design variables****
svyset sdmvpsu [pweight=wtmec4yr], strata(sdmvstra) vce(linearized)

svy, subpop(if ridageyr >=20 & ridageyr <.): mean ridageyr, over(race)
svy, subpop(if ridageyr >=20 & ridageyr <.): mean ridageyr, over(riagendr)

*age adjusted
svy, subpop(if ridageyr >=20 & ridageyr <.): mean hbpx, stdize(age) stdweight(std_wgt)
svy, subpop(if ridageyr >=20 & ridageyr <.): mean hbpx, stdize(age) stdweight(std_wgt) over(riagendr)
svy, subpop(if ridageyr >=20 & ridageyr <.): mean hbpx, stdize(age) stdweight(std_wgt) over(race)
svy, subpop(if ridageyr >=20 & ridageyr <.): mean hbpx, stdize(age) stdweight(std_wgt) over(riagendr race)


*unadjusted
svy, subpop(if ridageyr >=20 & ridageyr <.): mean hbpx
svy, subpop(if ridageyr >=20 & ridageyr <.): mean hbpx, over(riagendr)
svy, subpop(if ridageyr >=20 & ridageyr <.): mean hbpx, over(race)
svy, subpop(if ridageyr >=20 & ridageyr <.): mean hbpx, over(riagendr race)

log close