*****pgm: descriptive_geomeans.do****

use "C:\NHANES\Data\analysis_data.dta", clear



gen     age=1 if ridageyr >=20 & ridageyr <40
replace age=2 if ridageyr >=40 & ridageyr <60
replace age=3 if ridageyr >=60 & ridageyr <.

gen     race=1 if ridreth1==3
replace race=2 if ridreth1==4
replace race=3 if ridreth1==1
replace race=4 if ridreth1==2 | ridreth1==5

gen ln_lbxtc=ln(lbxtc)

****format variables******
label define agefmt 1 "20-39"
label define agefmt 2 "40-59", add
label define agefmt 3 "60+", add

label define racefmt 1 "NH White", 
label define racefmt 2 "NH Black", add
label define racefmt 3 "Mex American", add
label define racefmt 4 "Other race/ethn", add

label define sexfmt 1 "male"
label define sexfmt 2 "female", add

label values age agefmt
label values riagendr sexfmt
label values race racefmt

log using "c:\NHANES\log\descriptive_geomeans.log", replace


****specify survey design variables****
svyset sdmvpsu [pweight=wtmec4yr], strata(sdmvstra) vce(linearized)

quietly svy, subpop(if ridageyr >=20) vce(linearized): mean ln_lbxtc, 
ereturn display, eform(geo_mean)

quietly svy, subpop(if ridageyr >=20) vce(linearized): mean ln_lbxtc, over(riagendr)
ereturn display, eform(geo_mean)

quietly svy, subpop(if ridageyr >=20) vce(linearized): mean ln_lbxtc, over(riagendr age)
ereturn display, eform(geo_mean)

log close